13 ファイルと標準入出力

import std.stdio;

void main()
{
    auto f1 = File("foo.txt", "w");     // 書き込みモードで開く
    f1.writeln("くぁｗせｄｒｆｔｇｙふじこｌｐ；");

    {
        auto f2 = f1;                   // sameFileはf1と同じファイルを指す
        f2.write("ふぉおばｒほげ");
    }

    f1 = File("hoge.txt", "w");         // 違うファイルを開く
                                        // foo.txtは自動的にで閉じられる。

    // Fileは、同じファイルを参照しているすべてのFile構造体がなくなれば、自動的に閉じられる。
    // 明示的にファイルを閉じたいのであれば、File.detach()を使う
    f1.detach();                        // file.close()が呼ばれる
}

import std.stdio;

void main()
{
    auto f = File("foo.txt", "w");
    int[] data = [1, 2, 3, 4, 5];

    f.rawWrite(data);
}

01 00 00 00 02 00 00 00 03 00 00 00 04 00 00 00 05 00 00 00 

import std.file;

void main()
{
    int[] data = [0, 1, 2, 3, 4];

    std.file.write("foo.dat", data);        // foo.datが無ければ新しくファイルが作られる
    std.file.append("bar.dat", data);       // bar.datがない場合は、write同様に新しく作られる

    std.file.write("foo.dat", "ふー");        // foo.datを文字列で上書きする
    std.file.append("bar.dat", "ばー");       // bar.datに文字列を追加
}

import std.stdio;

void main()
{
    writeln("Hello, World!");   // 標準出力(コンソール)に出力される

    stdout.rawWrite("foo bar\n"); // 同上
}

import std.stdio;

void main()
{
    auto file = File("foo.txt");

    string str = file.readln();
    writeln(str);
}

import std.ascii,
       std.stdio;

void main()
{
    {
        auto file = File("foo.txt", "w");
        file.writeln("123x345");           // foo.txtに"123x345\n"を書き込む
        file.writeln("foo-bar");
    }

    auto file = File("foo.txt");
    int a = void, b = void;

    // foo.txtから、"%sx%s"というフォーマットで2つの整数を読み込む
    // `&a`というように、ポインタを渡す
    file.readf("%sx%s", &a, &b);

    writefln("%s : %s", a, b);          // 123 : 345

    // 改行文字分だけ進める
    file.seek(std.ascii.newline.length, SEEK_CUR);

    string str1 = void, str2 = void;

    // "%s-%s"というフォーマットとなっているテキストを読む
    file.readf("%s-%s" ~ newline, &str1, &str2);
    writefln("%s : %s", str1, str2);
}

出席番号,点数
1,68
2,72
3,45
4,83
5,53
6,75
7,99
8,77
9,101
10,22

import std.conv,
       std.range,
       std.stdio;

void main()
{
    immutable filename = "input.csv";

    auto file = File(filename);
    file.byLine.popFront();         // 1行捨てる

    int[] points;

    // ファイルを各行取得する。
    // KeepTerminator.noを指定すると、改行文字がlineの末尾に現れなくなる
    // lineはstring型
    foreach(line; file.byLine(KeepTerminator.no)){
        // 行をカンマ","で区切り、2つ目の要素を数値(int)に変換する
        points ~= line.split(",")[1].to!int();
    }

    // 平均
    immutable mean = {
        real sum = 0;
        foreach(e; points)
            sum += e;

        return sum / points.length;
    }();

    // 標準偏差
    immutable devi = {
        real sum = 0;
        foreach(e; points)
            sum += (e - mean) ^^ 2;

        return (sum / points.length) ^^ 0.5;
    }();

    // 全員の偏差値
    real[] scor;
    foreach(e; points)
        scor ~= 10 * (e - mean) / devi + 50;

    writefln("Mean: %s", mean);
    writefln("Standard Deviation: %s", devi);
    writefln("Standard Score: \n%(%s\n%)", scor);
}

Mean: 69.5
Standard Deviation: 22.9532
Standard Score:
49.3465
51.0892
39.3261
55.8815
42.8115
52.3962
62.8522
53.2675
63.7236
29.3057

import std.stdio;


void main(){
    immutable filename = "data.dat";
    auto file = File(filename);

    foreach(buf_; file.byChunk(26 << 20)){
        // buf_はbyChunkによって使いまわされるので、
        // もしbuf_を書き換えるか、
        // ループを抜けてもbuf_を保存しておきたいのであれば、
        // .dupでコピーをとっておく
        auto buf = buf_.dup;

        // bufに対する処理
    }
}

import std.stdio;

void main(){
    auto bs = cast(ubyte[])read("data.dat");        // data.datをまるごと読み込む

    auto str = readText("foo.txt");                 // テキストとして読み込む
}

import std.conv,
       std.string,
       std.stdio;

void main()
{
    write("Please put a number and press the Enter Key. ---- ");

    immutable n = readln()      // 1行読み込んで
                  .chomp()      // 末尾の改行を消して
                  .to!int();    // intに変換

    write("Please put a number and press the Enter Key. ---- ");

    immutable m = readln()      // 1行読み込んで
                  .chomp()      // 末尾の改行を消して
                  .to!int();    // intに変換

    writefln("Sum of the numbers you entered is %s.", n + m);
}